近期有Win11用戶想要將自己常用的軟件,添加到Win11右鍵菜單中,這樣自己可以隨時(shí)的找到并打開該應(yīng)用,那么應(yīng)該如何設(shè)置呢?本期教程小編將以添加畫圖程序?yàn)槔,帶大家了解詳?xì)的添加步驟,操作簡(jiǎn)單,安全有效,感興趣的朋友們可以試著操作看看哦。
具體操作如下:
1. 在桌面空白的地方,點(diǎn)擊【右鍵】,打開的右鍵菜單項(xiàng)中,選擇【新建 - 文本文檔】;
2. 新建 文本文檔 - 記事本窗口,輸入以下命令:
- 01@echo off
- 02(PUSHD "%~DP0")&(REG QUERY "HKU\S-1-5-19">NUL 2>&1)||(powershell -Command "Start-Process '%~fdpnx0' -Verb RunAs"&&EXIT)
- 03title 在Win11下給圖片右鍵添加"用畫圖編輯"
- 04for /f "tokens=4 delims= " %%a in ('ver') do (for /f "tokens=1 delims=." %%b in ("%%a") do set num=%%b)
- 05if %num% LSS 10 echo 你的系統(tǒng)無(wú)需此操作 按任意鍵退出&pause>NUL&exit
- 06reg query "HKCR\Local Settings\Software\Microsoft\Windows\CurrentVersion\AppModel\PackageRepository\Extensions\ProgIDs\AppXcesbfs704v2mjbts9dkr42s9vmrhxbkj">nul 2>nul
- 07if %errorlevel% == 1 echo 未安裝畫圖 按任意鍵退出&pause>NUL&exit
- 08set /a menu=0
- 09echo 在Win11下給圖片右鍵添加"用畫圖編輯"&echo=&echo 1、添加或修復(fù)右鍵菜單 (由于微軟頻繁的自動(dòng)更新程序 所以需要經(jīng)常修復(fù))&echo=&echo 2、刪除右鍵菜單&echo=
- 10set /p menu=請(qǐng)選擇功能 (默認(rèn) %menu% 不做更改 直接退出):
- 11if %menu%==0 exit
- 12if %menu%==1 goto 1
- 13if %menu%==2 goto 2
- 14:1
- 15cls
- 16echo 正在添加或修復(fù)右鍵菜單 請(qǐng)稍候...
- 17for /f "tokens=1* delims= " %%a in ('reg query "HKCR\Local Settings\Software\Microsoft\Windows\CurrentVersion\AppModel\PackageRepository\Extensions\ProgIDs\AppXcesbfs704v2mjbts9dkr42s9vmrhxbkj"') do set mspaint=%ProgramFiles%\WindowsApps\%%a\PaintApp\mspaint.exe
- 18set all=avci,avif,bmp,dib,emf,gif,heic,heif,hif,ico,jfif,jpe,jpeg,jpg,png,rle,tif,tiff,webp,wmf
- 19for %%i in (%all%) do ( REG delete HKCU\Software\Classes\SystemFileAssociations\.%%i\shell\用畫圖編輯 /f /reg:64>nul 2>nul
- 20REG ADD "HKCU\Software\Classes\SystemFileAssociations\.%%i\shell\用畫圖編輯" /v "icon" /t REG_SZ /d "%mspaint%" /f /reg:64>nul
- 21REG ADD "HKCU\Software\Classes\SystemFileAssociations\.%%i\shell\用畫圖編輯\Command" /v "" /t REG_SZ /d "\"%mspaint%\" \"%%1\"" /f /reg:64>nul
- 22)
- 23cls
- 24echo 操作完成 請(qǐng)按任意鍵退出&pause>NUL&exit
- 25:2
- 26cls
- 27echo 正在刪除右鍵菜單 請(qǐng)稍候...
- 28set all=avci,avif,bmp,dib,emf,gif,heic,heif,hif,ico,jfif,jpe,jpeg,jpg,png,rle,tif,tiff,webp,wmf
- 29for %%i in (%all%) do ( REG delete HKCU\Software\Classes\SystemFileAssociations\.%%i\shell\用畫圖編輯 /f /reg:64>nul 2>nul )
- 30cls
- 31echo 刪除完成 請(qǐng)按任意鍵退出&pause>NUL&exit
復(fù)制代碼
@echo off
(PUSHD "%~DP0")&(REG QUERY "HKU\S-1-5-19">NUL 2>&1)||(powershell -Command "Start-Process '%~fdpnx0' -Verb RunAs"&&EXIT)
title 在Win11下給圖片右鍵添加"用畫圖編輯"
for /f "tokens=4 delims= " %%a in ('ver') do (for /f "tokens=1 delims=." %%b in ("%%a") do set num=%%b)
if %num% LSS 10 echo 你的系統(tǒng)無(wú)需此操作 按任意鍵退出&pause>NUL&exit
reg query "HKCR\Local Settings\Software\Microsoft\Windows\CurrentVersion\AppModel\PackageRepository\Extensions\ProgIDs\AppXcesbfs704v2mjbts9dkr42s9vmrhxbkj">nul 2>nul
if %errorlevel% == 1 echo 未安裝畫圖 按任意鍵退出&pause>NUL&exit
set /a menu=0
echo 在Win11下給圖片右鍵添加"用畫圖編輯"&echo=&echo 1、添加或修復(fù)右鍵菜單 (由于微軟頻繁的自動(dòng)更新程序 所以需要經(jīng)常修復(fù))&echo=&echo 2、刪除右鍵菜單&echo=
set /p menu=請(qǐng)選擇功能 (默認(rèn) %menu% 不做更改 直接退出):
if %menu%==0 exit
if %menu%==1 goto 1
if %menu%==2 goto 2
:1
cls
echo 正在添加或修復(fù)右鍵菜單 請(qǐng)稍候...
for /f "tokens=1* delims= " %%a in ('reg query "HKCR\Local Settings\Software\Microsoft\Windows\CurrentVersion\AppModel\PackageRepository\Extensions\ProgIDs\AppXcesbfs704v2mjbts9dkr42s9vmrhxbkj"') do set mspaint=%ProgramFiles%\WindowsApps\%%a\PaintApp\mspaint.exe
set all=avci,avif,bmp,dib,emf,gif,heic,heif,hif,ico,jfif,jpe,jpeg,jpg,png,rle,tif,tiff,webp,wmf
for %%i in (%all%) do ( REG delete HKCU\Software\Classes\SystemFileAssociations\.%%i\shell\用畫圖編輯 /f /reg:64>nul 2>nul
REG ADD "HKCU\Software\Classes\SystemFileAssociations\.%%i\shell\用畫圖編輯" /v "icon" /t REG_SZ /d "%mspaint%" /f /reg:64>nul
REG ADD "HKCU\Software\Classes\SystemFileAssociations\.%%i\shell\用畫圖編輯\Command" /v "" /t REG_SZ /d "\"%mspaint%\" \"%%1\"" /f /reg:64>nul
)
cls
echo 操作完成 請(qǐng)按任意鍵退出&pause>NUL&exit
:2
cls
echo 正在刪除右鍵菜單 請(qǐng)稍候...
set all=avci,avif,bmp,dib,emf,gif,heic,heif,hif,ico,jfif,jpe,jpeg,jpg,png,rle,tif,tiff,webp,wmf
for %%i in (%all%) do ( REG delete HKCU\Software\Classes\SystemFileAssociations\.%%i\shell\用畫圖編輯 /f /reg:64>nul 2>nul )
cls
echo 刪除完成 請(qǐng)按任意鍵退出&pause>NUL&exit
3. 接著點(diǎn)擊左上角的【文件】,在打開的下拉項(xiàng)中,選擇【 另存為 (Ctrl + Shift + S) 】;
4. 另存為窗口,注意三個(gè)地方:
1)文件另存為的路徑
2)文件名填入以【.bat】結(jié)尾的名稱,保存類型選擇【所有文件】
3)編碼選擇【ANSI】
最后點(diǎn)擊【保存】。
5. 找到并選擇剛才另存為.bat后綴的文件,點(diǎn)擊【右鍵】,在打開的右鍵菜單項(xiàng)中,選擇【以管理員身份運(yùn)行】;
6. 用戶賬戶控制窗口,你要允許此應(yīng)用對(duì)你的設(shè)備進(jìn)行更改嗎?點(diǎn)擊【是】;
7. 輸入數(shù)字【1】,并按【回車】,命令執(zhí)行完成后,按【任意鍵】退出即可;
8. 照片上點(diǎn)擊【右鍵】,就可以選擇【用畫圖編輯】了。
更多好用系統(tǒng)推薦
2024最新Win11下載合集
Win11家庭中文版下載推薦
最好的Windows11 64位純凈版系統(tǒng)推薦
以上就是系統(tǒng)之家小編為你帶來(lái)的關(guān)于“Win11右鍵添加畫圖程序的簡(jiǎn)單步驟”的全部?jī)?nèi)容了,希望可以解決你的問(wèn)題,感謝您的閱讀,更多精彩內(nèi)容請(qǐng)關(guān)注系統(tǒng)之家官網(wǎng)。
發(fā)表評(píng)論
共0條
評(píng)論就這些咯,讓大家也知道你的獨(dú)特見解
立即評(píng)論以上留言僅代表用戶個(gè)人觀點(diǎn),不代表系統(tǒng)之家立場(chǎng)